Jörg Kliemann, Höhere landwirtschaftliche Bundeslehranstalt St.Florian

Wann ist der Faschingsdienstag im Jahr 2000?
oder: Wer war C.F. Gauss? 

Mathematische Inhalte:

Modularithmetik, Kalender.

Anwendung:

Berechung des Datums des Faschingsdienstag aus dem Osterdatum, zur Verwendung in Vertretungstunden, Faschingsstunden, Weihnachtsstunden, ...

Mediales Umfeld:

Verwendetes Programm: Excel 5.0
Dateien zum Herunterladen: FASCHING.XLS

1. Gausssche Osterformel für den gregorianischen Kalender
 

Es sei J die Jahreszahl des gewünschten Jahres.
Weiters seien a = J mod 19 , b = (19a+m) mod 30 , c = (2(J mod 4) + 4(J mod 7) + 6b + n) mod 7,
d = b + c .

Korrekturen:
d = 28, wenn d=35 (z.B.: 1981)
d = 27, wenn (a>10) und (b=28) und (c=6) (z.B. 1954)

Die Konstanten m und n ergeben sich aus folgender Tabelle:
J = 1583 .. 1699: n = 22, m = 2
J = 1700 .. 1799: n = 23, m = 3
J = 1800 .. 1899: n = 23, m = 4
J = 1900 .. 2099: n = 24, m = 5
J = 2100 .. 2199: n = 24, m = 6
J = 2200 .. 2299: n = 25, m = 0

Dann fällt der Ostersonntag auf den (22+d)ten März bzw. auf den (d-9)ten April.

Damit fällt der Faschingsdienstag auf den (3+d)ten ((4+d)ten, wenn J ein Schaltjahr ist) Februar bzw. auf den (d-25)ten April.

Zur vereinfachten Rechnung nehmen wir den 22. März als Basisdatum. Dann fällt der Faschingsdienstag auf Basisdatum - (47-d) Tage.

2. Modellierung in der Tabellenkalkulation

A1: Berechnung des Datums des Faschingsdienstag
A2: Jahr
B2: a
C2: b
D2: c
E2: d
F2: Basisdatum
G2: Faschingsdienstag
A3: 1995
B3: =REST(A3;19)
C3: =REST(19*B3+24;30)
D3: =REST(2*REST(A3;4)+4*REST(A3;7)+6*C3+5;7)
E3: =WENN(ODER(UND(C3=28;D3=6;B3>10);C3+D3=35);C3+D3-7;C3+D3)
F3: 1995-3-22
G3: F3-47+E3

Den Bereich A3:G3 markieren und mit Hilfe der Auto-Fill-Funktion einmal kopieren.
  Folgende Zellen überschreiben:
A4: 1996
F4: 1996-3-22
Den Bereich A3:G4 markieren und mit Hilfe der Auto-Fill-Funktion beliebig oft kopieren.
   

Erfreulich: Der letzte Fasching in diesem Jahrhundert und -tausend dauert sehr lange (7.3.2000).
Minusrekord: Der kürzeste Fasching dauert nur bis 5.2.2008.

3. PS: Statistik für Freitag, 13.

A1: 1950-01-13
A2: 1950-02-13
B1: =WENN(WOCHENTAG(A1)=6;1;0)
B2: = WENN(WOCHENTAG(A2)=6;1;0)
Den Bereich A1:B2 markieren und mit Hilfe der Auto-Fill-Funktion bis A1:B1200 kopieren.
D1: H(Freitag)=
E1: =SUMME(B1:B2000)/ANZAHL(B1:B2000)

Die Häufigkeit des Ereignisses, daß ein 13. auf einen Freitag fällt, ist höher als für einen anderen Wochentag (vgl. mit 1/7 = 0.142857).